KMS服务器端：
wget --no-check-certificate https://raw.githubusercontent.com/Mr-xn/kms-server-deploy/master/kms-server-deploy.sh && bash kms-server-deploy.sh
客户端激活脚本：
@echo off
title 内网kms激活助手
cls
::申请管理员权限
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
:start
cls
echo 注意：仅在内网情况下可以激活
echo.
echo 正在检查与激活服务器的连接情况......请耐心等待
ping -n 1 192.168.160.15 | find "超时" > NUL && goto fail
ping -n 1 192.168.160.15 | find "目标主机" > NUL && goto fail
ping -n 1 192.168.160.15 | find "无法访问" >nul && goto fail
ping -n 1 192.168.160.15 | find "故障" >nul && goto fail
ping -n 1 192.168.160.15| find "找不到" >nul && goto fail
echo 成功连接
echo.
:menu
echo 请选择项目:
echo = = = = = = = = = = = = = = = = = = = = = =
echo 【1】设置 Windows 激活服务器（加域电脑无需）
echo 【2】设置 Office LTSC 激活服务器 (office16以上)
echo.
echo 【3】安装 Windows10 Pro 密钥（Win11 Pro通用）
echo 注意：本工具仅帮助连接内网的激活认证服务器
echo 【0】检查激活状态
echo = = = = = = = = = = = = = = = = = = = = = =
echo.
:select
set /p a=请输入数字后回车:
If "%a%"=="0" goto check
If "%a%"=="1" goto Windows
If "%a%"=="2" goto Office16
If "%a%"=="3" goto 10key
echo.&echo 输入无效，请重新输入.
pause >nul
goto select
:Windows
cls
echo -------------------------------------------
echo 连接激活服务器...
slmgr /skms 192.168.160.15:1688
echo 重启激活服务...
slmgr /ato
echo -------------------------------------------
echo.
echo 请查看是否完成
echo.
pause
cls
goto menu
:Office16
cls
echo -------------------------------------------
echo 连接激活服务器...
cd "C:\Program Files (x86)\Microsoft Office\Office16"
cscript ospp.vbs /sethst:192.168.160.15
echo 重启激活服务...
cscript ospp.vbs /act
echo -------------------------------------------
echo.
echo 请查看是否完成
echo.
pause
cls
goto menu
:10key
echo 正在安装 Windows10 Pro 密钥...（Win11通用）
slmgr /ipk W269N-WFGWX-YVC9B-4J6C9-T83GX
echo 完成
echo.
pause
cls
goto menu
:check
cls
echo office激活查看命令行窗口，系统激活会弹出窗口
echo.
cscript "C:\Program Files (x86)\Microsoft Office\Office16\ospp.vbs" /dstatus
echo.
echo 以上为office激活状态
echo.
slmgr.vbs -dli
pause
cls
goto menu
:fail
echo.
echo 无法连接到服务器 QAQ
echo.
pause
exit
2022-06-21 
